Wikidata:WikiProject Sculpture

#title:Count of sculptures known to Wikidata
SELECT (COUNT(DISTINCT ?item) AS ?count) WHERE {
?item wdt:P31/wdt:P279* wd:Q860861
}

#title:Wikis with pages about individual sculptures
SELECT ?wiki ?wikinameLabel (COUNT(?site) AS ?count) WITH {SELECT DISTINCT ?item WHERE {
?item wdt:P31/wdt:P279? wd:Q860861 } } AS %toplist WHERE {
INCLUDE %toplist.
?site schema:about ?item ; schema:isPartOf ?wiki .
  OPTIONAL { ?wikiname wdt:P856 ?wiki }
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?wiki ?wikinameLabel ORDER BY DESC(?count)

#title:The most notable sculptures
#defaultView:ImageGrid
SELECT ?item ?itemLabel (SAMPLE(?img) AS ?image) WITH {SELECT DISTINCT ?item WHERE {
?item wdt:P31/wdt:P279? wd:Q860861.
?item wikibase:sitelinks ?sites. } ORDER BY DESC(?sites) LIMIT 100 } AS %toplist WHERE {
INCLUDE %toplist.
?item wdt:P18 ?img.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?item ?itemLabel

#title:The most notable sculptures without a co-ordinate location
#defaultView:ImageGrid
SELECT ?item ?itemLabel (SAMPLE(?img) AS ?image) WITH {SELECT DISTINCT ?item WHERE {
?item wdt:P31/wdt:P279? wd:Q860861.
  MINUS {?item wdt:P625 []}
?item wikibase:sitelinks ?sites. } ORDER BY DESC(?sites) LIMIT 100 } AS %toplist WHERE {
INCLUDE %toplist.
?item wdt:P18 ?img.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?item ?itemLabel

#title:Map of sculptures
#defaultView:Map{"hide": ["?coords", "?image"]}
SELECT ?item ?itemLabel (SAMPLE(?img) AS ?image) ?coords WHERE {
?item wdt:P31/wdt:P279? wd:Q860861;
  wdt:P625 ?coords;
  wdt:P18 ?img
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?item ?itemLabel ?coords

#title:Map of birthplaces of sculptors
#defaultView:Map{"hide": ["?coords"]}
SELECT DISTINCT ?sculptor ?sculptorLabel ?coords WITH {SELECT DISTINCT ?item WHERE {
?item wdt:P31/wdt:P279? wd:Q860861 }  } AS %list WHERE {
INCLUDE %list.
?item wdt:P170 ?sculptor. ?sculptor wdt:P19/wdt:P625 ?coords;
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

#title:External identifiers used for sculptures
SELECT ?id ?idLabel ?statedLabel (COUNT(?value) AS ?count) WITH {
  SELECT DISTINCT ?item WHERE {
     ?item wdt:P31/wdt:P279? wd:Q860861.
  }
} AS %subquery WHERE {
  INCLUDE %subquery .
  ?id wikibase:propertyType wikibase:ExternalId; wikibase:claim ?p; wikibase:statementProperty ?ps.
  ?item ?p [ ?ps ?value ] . OPTIONAL {?id wdt:P9073 ?stated}
#  ?id rdfs:label ?idlabel FILTER (lang(?idlabel) = "en").
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
} GROUP BY ?id ?idLabel ?statedLabel
ORDER BY DESC(?count)